
一、项目简介
红外线是波长介乎微波与可见光之间的电磁波，由于其发射简单、成本低廉等特点，广泛应用于家电的遥控。随着家中红外控制设备的增多，各种遥控器成为生活中的麻烦事。本项目从红外信号分析入手，将红外信号理论与单片机控制相结合，深入研究红外线接发的工作机制，并实现将arduino作为红外接发中介，以单一的“控制遥控器”对所有家电进行控制。在此基础上，增加网络控制模块，实现室内环境的实时监测上传与设备的远程控制。如此，可以实现下班前将家中空调开启，回到家便享受清凉的美事。

作品图：
[image: IMG_20131021_234022][image: fzz]

二、设计由来
之前在初中时搞过一段时间avr，之后一直忙于学业，无暇顾及单片机行业的发展。这次arduino竞赛提供了一个极佳的机会，让我了解arduino这一全新的领域。参加比赛可谓现学现用，在看教程时，突然对红外发射接收感兴趣，于是就结合之前的想法，想做一个红外控制器。
设想只需一个遥控器就可控制家中所有用红外控制的家电，后来知道这就是红外转码功能。通过程序制定“控制遥控器”各键功能，通过模式切换实现对不同电器的转换，红外接收器接收到控制遥控器的指定按键后，经arduino按预先设定的对应关系，发射相应的红外指令。
控制遥控器

IRromote库中的IRrecvDump与IRsendDemo例子分别举例了接受、发射红外代码的使用方法，基于这两个程序，构成了我的红外转码程序。
鉴于家中和寝室的红外控制设备有限，仅以格力空调、美的电扇、iptv创维电视为例设计红外转码功能。

[bookmark: _Toc370212350]三、开发流程
[bookmark: _Toc370212351]（一）红外转码部分
[bookmark: _Toc370212352]1.使用IRrecvDump接受各电器红外编码
红外遥控器发射的其实是一连串的方波信号，接收器根据信号有无及其间隔的时间长度计算所代表的1/0信号。
下图是常用的NEC编码方式（也是本项目中电扇和iptv的编码方式）。NEC编码由十六位二进制数构成，前八位是地址，后八位是命令。
[image: ]
红外NEC协议原理
发送信号时，首先是一段9ms高电平和一段4.5ms低电平作为开始标记，随后是信号内容。
先是8位的地址及其反向编码（确保信息准确），再是8位的命令编码及其反向编码。最后以一小段高电平结束。
知道了NEC的编码形式，我们就可以通过读取遥控器的红外指令，得到各个信号的代码，并依照其编码方式发射NEC信号。
硬件部分：
连接非常简单，只需将三个引脚接到指定位置即可。
[image: ]
红外接收头及接法
软件部分：
好在IRromte库十分强大，其IRrecvDump的example可以将读取的红外信息直接打印到Serial Monitor。
例如，项目中的总控制遥控器的第一个按钮的dump结果如下：
FFA25D
Decoded NEC: FFA25D (32 bits)
Raw (72): 18448 8900 -4450 550 -550 600 -500 600 -550 550 -550 600 -500 600 -550 550 -550 550 -550 600 -1600 600 -1650 600 -1650 550 -1650 600 -1650 550 -1650 600 -1600 600 -1650 550 -1650 600 -550 550 -1650 600 -550 550 -550 550 -550 600 -1600 600 -550 600 -500 600 -1650 550 -550 550 -1650 600 -1650 600 -1650 550 -500 600 -1650 600 26086 8900 -2200 600
“FFA25D”就是转换成16进制的编码，之后只要用它发射就行了。“NEC”代表程序已判断出这种型号的形式是NEC格式的。“32 bits”代表编码长度。后面的Raw是每个方波的长度。正值代表高电平，负值代表低电平，数值大小代表持续长度。根据NEC规则，一高一低的一组电平变化代表一个数。若560us高电平1690us低电平代表1,560us高电平560us低电平代表0，由于程序精度限制，只能以50us为倍数测量，所以只能看到近似的结果，但是这样的分辨率下分辨1与0自然是没有问题的。程序已经帮我们计算好信号的编码了，只要用就行。
[image: ]
红外NEC协议原理

一个个按钮点过去，获取各键编码
详见 遥控器编码.xls
有些编码形式特殊（如格力空调），将在第三步中阐述。

[bookmark: _Toc370212353]2.发射红外编码
收集完所有编码后，就可以尝试发射编码了。
硬件部分：
参考http://www.geek-workshop.com/thread-3444-1-1.html
[image: 8ae7bacftw1e23k0iqr6dj.jpg]
红外发射连接示意图
一开始一直感觉功率不够，一定要很近才行。于是尝试改小电阻，增加发射头数量等方式。
[image: IMG_20131002_155554]
增加发射头
红外线虽然肉眼不可见，但在镜头下是可以看到的！用此方法可以快速判断线路通断。
改小电阻对单片机有危险，而增加发射头效果依然不理想，于是考虑用三极管放大。经网友点拨，红外的方波信号需要三极管处在饱和区。经理论计算设计下图所示电路，实际测试各点电压值标在图上：
[image: triodeact]
通过三极管放大发射红外信号电路图及各点电压测量图

软件部分：
IRromte库提供了多种发射编码的函数。因为是NEC编码，所以使用的是void IRsend::sendNEC(unsigned long data, int nbits)，直接将刚才得到的十六进制编码值给这个函数就可以了。data代表发送的NEC编码值，nbits是编码长度。
例如
IRsend irsend;
irsend.sendNEC(0xFFA25D ,32);
另一种发射的函数是void IRsend::sendRaw(unsigned int buf[], int len, int hz)，有些不使用编码协议的信号要用它发射。
三个参数分别代表要发送的数组，数组长度，和发送红外光的频率（一般都是38（khz））。
例如创维电视开机信号：
unsigned int tvonoff[68]={4500, 4400,600, 550,550, 1650,600, 1600,600, 1650,550, 550,600, 500,600, 500,600, 550,550, 550,600, 1600,600, 1600,600, 1650,600, 500,600, 500,600, 500,600, 550,600, 500,600, 500,600, 1600,600, 1650,600, 500,600, 500,600, 500,600, 550,600, 1600,600, 1600,600, 550,600, 500,600, 1600,600, 1650,550, 1650,600, 1600,600};//已去除第一个值
IRsend irsend;
irsend. sendRaw (tvonoff,68,38);

[bookmark: _Toc370212354]3.格力空调的编码方式及发射方式
开发中遇到的一大问题就是格力空调的编码问题。
格力空调不知是出于什么样的心态，特立独行地设计了自己的一套编码方式，但奇怪之处在于通过sendRaw也不能实现控制。
在网友的启发下总算明白了编码机制。
竟然在一个信号中间部分空出一段20000us的低电平！！前后两部分还有某种特殊关系。所以用红外接收头dump出的就是有问题的代码，当然发射不出正确的。
而且与风扇等信号不同，空调遥控器发射的是状态信号，不是功能信号。每一个信号中完整包含了空调状态的所有信息（温度、模式、扫风……）所以按下升温降温后，发射的不是升降温的指令，而是当前状态加减一度后的新状态编码。编码中每一位数起什么功能都是定好的，比如说温度信息就体现在第3、4和第17、18位上。
根据上述两个例子的代码，自己改了改，总算成功实现控制。

[bookmark: _Toc370212355]4.加装温湿度传感器
想法是检测室温（湿度），当达到一定温度时自动开启风扇空调。
硬件部分：
使用的是DHT11的温湿度传感器。
[image: dht11]
DHT11接线方法图
按图接线，其中引脚3不用接线！
软件部分：
从网上找了一个库，直接照它的代码用就行了。
获取温度：
int dat;
int chk = DHT11.read(DHT11PIN);
return dat=(float)DHT11.temperature;
获取湿度：
  int dat; 
  int chk = DHT11.read(DHT11PIN);
  return dat=(float)DHT11.humidity;

[bookmark: _Toc370212356]5.加装蜂鸣器提示
Arduino最终需要用电池驱动，没有电脑端口，所以Serial的print信息不能被看到。需要加上一个指示装置表达当前运行状态，避免造成混乱。就从最简单的无源蜂鸣器开始。
设定蜂鸣器声音含义
程序调用void warning(int freq, int time)发声，通过改变两个参数实现不同声音。freq代表声音频率，1最高4最低，time代表声音时长，25最短100最长
	
	int freq
	int time

	Typechangebuzz(repeat times is mode number)
	1
	25

	Signal sending
	2
	50

	Cannot find number_in_mp3
	3
	50

	Temperature incorrect
	4
	100

	Other no function button
	Silent
	Silent


蜂鸣器声音含义表

硬件方面：
采用lcd1602的液晶屏加装转I2C口芯片，将十几个口简化为四个口。
四条线从上到下分别接arduino的GND、5V、A4、A5
[image: 8115486011_a99d721319_b]
Lcd1602+I2c转换模块实物图
软件部分 ：
参考了网上的资料，结合程序内容修改。
http://forum.arduino.cc/index.php?topic=128635.msg967608
Serial输出与lcd输出之间必然有冲突！！！需要删除所有Serial。

7.设计的控制遥控器使用方法：

Mode1：Air-conditioner     	   Mode2：Fan	 	         Mode3：Iptv  
控制遥控器三种模式下按键效果示意图

空调模式下数字需要连续输入两个，先十位数后个位数，且范围在18-30度之间，否则报警且需重新输入


到这里为止，就把红外转码部分的内容介绍完了。

[bookmark: _Toc370212358]（二）网络控制部分
红外控制的功能已经实现，接下来就是项目的优化过程。
最先想到的就是基于网络实现远程控制。后来知道，这就是物联网的概念。思路是这样的，通过温湿传感器反馈当前环境的温湿度，将数据上传到网络，如果到了警示值，通过邮件、微博通知用户，用户打开控制页面，发送指令（如开空调），uno定时访问网络，当发现需要执行指令时，发射相应的红外指令（空调开启）。
 (

硬件方面：
本项目联网的组件使用的W5100。W5100是uno的扩展，直接在uno上叠起来就可以使用。
由于遇到红外接收与网络连接端口的冲突问题。采用两块uno分别实现各功能。一块红外转码，另一块网络通信。两者的通信方式直接采用红外。也就是，原有的uno（控制uno）接线不变，新的uno搭载w5100（网络uno），并用红外发射管向红外接收器发射信号，实现单向的信息传输，且传送的信息就是控制遥控器的按键信息，发射头就放在接收头下。 单向传输的特性决定了温湿度传感器不能向网络uno传输数据，所以就调整到网络uno上接收温湿度传感器值。
最后加上一个重复发射按钮发射上一个信号以便调试时测试响应距离。
这样就完成了硬件部分的所有连接。
附上局部图：
[image: IMG_20131021_234120]
红外接收器、发射二极管、蜂鸣器、温度传感器等实物连接图
其中下侧黄色和蓝色线连接网络uno

软件方面：
必须承认，网络控制方面，最主要和最烦人的是程序和配置的问题。
主流的物联网平台有亿联与乐联网。本项目采用的是亿联（yeelink）平台，虽然功能没有乐联网那么全，但是亿联不用设置网关，而且没有传感器数量限制。
根据某大神的代码更改完成了功能。
http://hi.baidu.com/mizuda/item/fdd9c38a8e8237d9d1f8cdf6
首先要了解上传下载的流程，这需要涉及到http的知识。基本原理是，连入网络后，如需下载某开关值，需要先用client,print以http格式发送设备、开关编号及你的U-ApiKey号码（为了身份认证），服务器会返回一串Json代码，通过读取某一特定位置（倒数第二位）的值来判断开关的状态；如需上传，需要用client.print将待上传的值以特定的http格式，连同设备、传感器号及U-ApiKey发送。
需要注意的是，下载是分发送与接收两个步骤进行的。
Yeelink在警示方面做得也是不错的，主要有邮件与微博警报，可以在yeelink用户中心进行设置，方法很简单，这里也不再阐述。
Yeelink还有手机app，使用起来同样很简单。
[image: Screenshot_2013-10-22-13-03-12]
手机app控制面板
[image: Screenshot_2013-10-22-13-04-40]
手机app中温度传感器变化曲线

[bookmark: _Toc370212359]四、心得体会
这样，项目就基本完成了，历时一个月，走过不少弯路，但是都一一化解，其中锻炼了我分析问题与解决问题的能力，这也是本次竞赛我最大的收获。
Arduino的功能是很强大的，也具有相当的趣味性，但是往往一些意想不到的状况会消磨新手的兴趣。所以本次项目完成后，借助极客工坊的平台，我将创作过程的详尽指导说明全部公开，包括图片视频效果展示与源代码。
http://www.geek-workshop.com/thread-7561-1-1.html
Arduino是软硬件全部开源的单片机，这一开放的想法是值得称赞的。我也希望开发者们能多多分享制作成果，引领新人们成长，同时推动arduino的进步。这也应该是arduino设计者们开源想要达到的目的。

[bookmark: _Toc370212360]五、成本估算：
2012最新款 Arduino UNO R3 开发板配SUB线   *2…………￥78
新版 Arduino Ethernet W5100 网络扩展板 SD卡扩展…………￥40
Arduino IIC/I2C/接口 LCD1602转接板 ………… ￥6.5
LCD1602A液晶特价促销…………￥8.2
AOSONG(奥松）DTH11温湿度传感器,DHT11温湿度模块  …………￥4.5
HS0038B HS0038B SIP3 红外遥控接收头 红外接收管 VISHAY  …………￥1.8
优质面包板/迷你小面包板/ 实验板 长8.5CM 宽5.5CM 可以组合拼接…………￥5.5
GP 超霸 无线话筒电池 玩具遥控器电池 6F22 9V电池 GP9V电池 *2 …………￥3.4
9V 电池盒 带线电池盒 不带盖 开关  *2…………￥3.6
蜂鸣器…………￥0.6
以上￥152.1

以下材料只使用部分
盒装14种长度140根优质跳线 面包板线 面包板专用线 面包板跳线…………￥10.0
面包线 面包板线 面包板扎线 连接线测试线 实验线杜邦线一捆65条…………￥5.3
常用小功率三极管包等17种170只  …………￥7.5
1/4W五色环电阻1%精密度 金属膜电阻包 30种常用阻值每种阻值20个  …………￥5.9
5MM发射管 940nm红外发射管（20只）  …………￥2.6
线束 杜邦线 彩排40P 双头1P 一头公一头母 长20CM 12股优质铜…………￥6.5
网线、焊锡、按钮开关费用不计
总计：￥152.1+￥37.8=￥189.9


[bookmark: _Toc370212361]六、程序代码：
控制uno：
主程序：
#define AIR_LOW 16
#define AIR_HIGH 30
#define WARNIGN_TEMP 28

//lcd
#define I2C_ADDR    0x27  // Define I2C Address where the PCF8574A is
#define BACKLIGHT_PIN     3
#define BACKLIGHT_POL POSITIVE
#define En_pin  2
#define Rw_pin  1
#define Rs_pin  0
#define D4_pin  4
#define D5_pin  5
#define D6_pin  6
#define D7_pin  7

#include <IRremote.h>
#include <Wire.h>
#include <LCD.h>
#include <LiquidCrystal_I2C.h>

#include "array_mp3.h"

//define pins
//pin 3 is used to emit
int Pin_Button_Resend = 4;
int PinBuzzer = 5;
int RECV_PIN = 6;
int PinTempsensor = 0;  //analog

LiquidCrystal_I2C lcd(I2C_ADDR,En_pin,Rw_pin,Rs_pin,D4_pin,D5_pin,D6_pin,D7_pin, BACKLIGHT_PIN, BACKLIGHT_POL);

//variables used in IRromote
IRrecv irrecv(RECV_PIN);
IRsend irsend;
decode_results IR_results;

unsigned long int LastTime_Button_Resend=0;//debounce

int type = 1;                        //1:air  2:fan  3:iptv
int inputnumber=-1;
int input_number_result=0;
int Pin_Button_Resend_Result=0;

int currenttem=27;
boolean Switch_Air_off = true;
boolean Switch_Fan_off = true;

double Temperature_Result;
unsigned long int Last_Signal=0xffffffff;

//gl
unsigned char glopen[9]={0x09,0x00,0xa0,0x50,0x02,0x00,0x20,0x00,0x50}; //16摄氏度开
unsigned char glclose[9]={0x01,0x0b,0xa0,0x50,0x02,0x00,0x20,0x00,0x80};//27摄氏度关

void sendpresumable()
{
  irsend.mark(9000);
  irsend.space(4500);
}   
void send0()
{
  irsend.mark(560);
  irsend.space(565);
}

void send1()
{
  irsend.mark(560);
  irsend.space(1690);
}

void sendGree(byte ircode, byte len)
{
  byte mask = 0x01;
  for(int i = 0;i < len;i++){
    if (ircode & mask)
      send1();
    else
      send0();
    mask <<= 1;
  }
}

void glon()
{
  irsend.enableIROut(38);
  sendpresumable();
  for(int i=0;i<=3;i++)
    sendGree(glopen[i], 8);
  sendGree(0x02, 3);
  irsend.mark(560);
  irsend.space(10000);
  irsend.space(10000);
  for(int i=5;i<=8;i++)
    sendGree(glopen[i], 8);
  irsend.mark(560);
  irsend.space(0);
  Switch_Air_off=false;
}

void gloff(){
  irsend.enableIROut(38);
  sendpresumable();
  for(int i=0;i<=3;i++)
    sendGree(glclose[i], 8);
  
  sendGree(0x02, 3);
  irsend.mark(560);
  irsend.space(10000);
  irsend.space(10000);
  
  for(int i=5;i<=8;i++)
    sendGree(glclose[i], 8);
  irsend.mark(560);
  irsend.space(0);
  Switch_Air_off=true;
}

void temset(int tem)
{
  if(tem<16||tem>30){
    warning(3,50);
    lcd.setCursor(0,1);
    lcd.print("Tem Incorrect   ");
    return;
  }
  lcd.setCursor(0,1);
  lcd.print("Temperature:    ");
  lcd.setCursor(12,1);
  lcd.print(tem,DEC);
  currenttem=tem;
  int incre=tem-16;
  glopen[1]+=incre*0x01;
  glopen[8]+=incre*0x10;
  if(glopen[8]>=256)
    glopen[8]-=256;
  //close code should be changed, but it's  ok if not to change it
  //glclose[1]+=incre*0x01;
  //glclose[8]+=incre*0x10;
  glon();
  glopen[1]=0x00;
  glopen[8]=0x50;
  irrecv.enableIRIn();
}
//gl end

void warning(int freq,int time)
{
  for(int i=0;i<time;i++){ 
    digitalWrite(PinBuzzer,HIGH);//make sound
    delay(freq); 
    digitalWrite(PinBuzzer,LOW);//not make sound
    delay(freq);
  } 
}
void Typechangebuzz(int type)
{
  for(int x=0;x<type;x++){
    warning(1,25);
    delay(200);
  }
}

//return the sequence number in mp3
//-1 means not fond
int number_in_mp3(long int data,unsigned long int array[])
{
  for(int i=0;i<21;i++){
    if(array[i]==data)
      return i;
  }
  warning(3,50);
  return -1;
}

void setup(){
  pinMode(PinBuzzer,OUTPUT);
  pinMode(Pin_Button_Resend,INPUT);
  lcd.begin (16,2);
  lcd.setBacklightPin(BACKLIGHT_PIN,POSITIVE);
  lcd.setBacklight(HIGH);
  lcd.home (); // go home
  lcd.print("infrared control"); 
  lcd.setCursor(0,1);
  lcd.print(" wait for order ");
  irrecv.enableIRIn(); // Start the receiver 
}

void loop() {
  if (irrecv.decode(&IR_results)) {
    irrecv.resume(); // Receive the next value
    inputnumber=number_in_mp3(IR_results.value,arraymp3);
    lcd.setCursor (0,1); 
    lcd.print("input:  th butto");    //clear old num
    lcd.setCursor (6,1); 
    lcd.print(inputnumber,DEC);
    delay(100);
    
    if(inputnumber==10){  //switch button
      if(type==1){
        type=2;
        Typechangebuzz(type);
        lcd.setCursor (0,0); 
        lcd.print("mode:2 fan      ");
      }
      else if(type==2){
        type=3;
        Typechangebuzz(type);
        lcd.setCursor (0,0); 
        lcd.print("mode:3 iptv     ");
      }
      else if(type==3){
        type=1;
        Typechangebuzz(type);
        lcd.setCursor (0,0); 
        lcd.print("mode:1 aircondit");
      }
      else{
        Typechangebuzz(5);
      }
      input_number_result=0;
      inputnumber=-1;
    }
    else if(inputnumber>=12&&inputnumber<=20){         //number1-9
      input_number_result=input_number_result*10+inputnumber-11;
    }
    else if(inputnumber==9){                          //number 0
      input_number_result=input_number_result*10;
    }

    if(type==1){
      if(input_number_result>=AIR_LOW&&input_number_result<=AIR_HIGH){
        warning(2,50);
        temset(input_number_result);
        delay(200);
        irrecv.enableIRIn();      //essential! or it won't recerive your next order 
        input_number_result=0;
      }
      else if(input_number_result>0&&input_number_result<=9){
        ;
      }
      else if(inputnumber==0){
        if(Switch_Air_off){
          lcd.setCursor(0,1);
          lcd.print("AirConditionerOn");
          temset(27);
          warning(2,50);
        }
        else{
          warning(2,50);
          gloff();
          lcd.setCursor(0,1);
          lcd.print("AirConditionerOf");
          Switch_Air_off=true;
        }
        delay(200);
        irrecv.enableIRIn();
        input_number_result=0;
      }
      else if(inputnumber==7){
        if(currenttem>16){
          temset(currenttem-1);
        }
        else{
          lcd.setCursor(0,1);
          lcd.print("Temp too low    ");
          warning(4,100);
        }
      }
      else if(inputnumber==8){
        if(currenttem<30){
          temset(currenttem+1);
        }
        else{
          lcd.setCursor(0,1);
          lcd.print("Temp too high   ");
          warning(4,100);
        }
      }
      else if(inputnumber==-1){
        ;
      }
      else{
        warning(4,100);
        input_number_result=0;
      }
    }

    else if(type==2){
      if(inputnumber==0){
        Last_Signal=fancode[0];//on/off
        lcd.setCursor(0,1);
        lcd.print("fan on/off      ");
      }
      else if(inputnumber==1){
        Last_Signal=fancode[3];//kind
        lcd.setCursor(0,1);
        lcd.print("fan mode change ");
      }
      else if(inputnumber==5){
        Last_Signal=fancode[2];//move
        lcd.setCursor(0,1);
        lcd.print("fan head move   ");
      }
      else if(inputnumber==8){
        Last_Signal=fancode[1];//speed
        lcd.setCursor(0,1);
        lcd.print("fan speed change");
      }
      else{
        return;
      }
      warning(2,50);
      irsend.sendNEC(Last_Signal,32);
      delay(200);
      irrecv.enableIRIn();
      input_number_result=0;
    }
    
    else if(type==3){
      if(inputnumber==0){
        Last_Signal=iptvcode[4];//on/off
        lcd.setCursor(0,1);
        lcd.print("iptv on/off     ");
      }
      else if(inputnumber==4){
        Last_Signal=iptvcode[1];//chan down
        lcd.setCursor(0,1);
        lcd.print("iptv channel  - ");
      }
      else if(inputnumber==5){
        Last_Signal=iptvcode[0];//chan up
        lcd.setCursor(0,1);
        lcd.print("iptv channel  + ");
      }
      else if(inputnumber==8){
        Last_Signal=iptvcode[2];//vol up
        lcd.setCursor(0,1);
        lcd.print("iptv volume   + ");
      }
      else if(inputnumber==7){
        Last_Signal=iptvcode[3];//vol down
        lcd.setCursor(0,1);
        lcd.print("iptv volume   - ");
      }
      else if(inputnumber==11){
        Last_Signal=iptvcode[5];//ok
        lcd.setCursor(0,1);
        lcd.print("iptv off confirm");
      }
      else{
        if(inputnumber==6){
          warning(2,50);
          irsend.sendRaw(tvonoff,68,38);
          lcd.setCursor(0,1);
          lcd.print("TV On/Off       ");
          delay(200);
          irrecv.enableIRIn();
          input_number_result=0;
        }
        return;
      }
      warning(2,50);
      irsend.sendNEC(Last_Signal,32);
      delay(200);
      irrecv.enableIRIn();
      input_number_result=0;
    }
  }  
  Pin_Button_Resend_Result=digitalRead(Pin_Button_Resend);
  if(Pin_Button_Resend_Result==HIGH&&millis()-LastTime_Button_Resend>200){ 
    irsend.sendNEC(Last_Signal,32);
    lcd.setCursor(0,1);
    lcd.print("Send last sygnal");
    warning(2,50);
    delay(200);
    irrecv.enableIRIn(); // Start the receiver
  }
}
Array_mp3.h文件：
unsigned long int arraymp3[]={
0xFFA25D, //MP3=>1#1
0xFF629D, //MP3=>1#2
0xFFE21D, //MP3=>1#3
0xFF22DD, //MP3=>2#1
0xFF02FD, //MP3=>2#2
0xFFC23D, //MP3=>2#3
0xFFE01F, //MP3=>3#1
0xFFA857, //MP3=>3#2
0xFF906F, //MP3=>3#3
0xFF6897, //MP3=>0
0xFF9867, //MP3=>4#2
0xFFB04F, //MP3=>4#3
0xFF30CF, //MP3=>1
0xFF18E7, //MP3=>2
0xFF7A85, //MP3=>3
0xFF10EF, //MP3=>4
0xFF38C7, //MP3=>5
0xFF5AA5, //MP3=>6
0xFF42BD, //MP3=>7
0xFF4AB5, //MP3=>8
0xFF52AD //MP3=>9
};

unsigned int tvonoff[68]={4500, 4400,600, 550,550, 1650,600, 1600,600, 1650,550, 550,600, 500,600, 500,600, 550,550, 550,600, 1600,600, 1600,600, 1650,600, 500,600, 500,600, 500,600, 550,600, 500,600, 500,600, 1600,600, 1650,600, 500,600, 500,600, 500,600, 550,600, 1600,600, 1600,600, 550,600, 500,600, 1600,600, 1650,550, 1650,600, 1600,600};

unsigned long int fancode[]=
{
  0x807FC03F,//on_off	NEC	
  0x807FE01F,//speed	NEC	
  0x807FC837,//move	NEC
  0x807FF00F//kind	NEC
};
unsigned long int iptvcode[]=
{
  0xCD32A15E,//chanup	NEC
  0xCD32619E, //chandown  NEC	
  0xCD3201FE,// volmup	NEC	
  0xCD32817E, //volmdown  NEC	
  0xCD323BC4, //on_off	NEC	
  0xCD32738C//ok NEC
};
网络uno：
/*
  this program is used to upload to web uno 
  network connection and get temperature and humidity from dht11
*/
#define DHT11PIN 2
// for yeelink api
#define APIKEY         "********" // replace with your API KEY
#define DEVICEID       5219 // replace with your device ID

#include <SPI.h>  
#include <Ethernet.h>
#include <Wire.h>  
#include <math.h>  
#include <IRremote.h>
#include <dht11.h>  

dht11 DHT11;

char flag =0;  
int currentmode=0;
boolean AcStateOff=true;
boolean FanStateOff=true;
boolean TVStateOff=true;

//AC FAN TV8523
String SENSORno[]={"8043","8017","8523"}; // sensor ID
IRsend irsend;

// assign a MAC address for the ethernet controller.
byte mac[] = { 0x00, 0x1D, 0x72, 0x82, 0x35, 0x9D};
// initialize the library instance:
EthernetClient client;
char server[] = "api.yeelink.net";   // name address for yeelink API

unsigned long lastConnectionTime = 0;          // last time you connected to the server, in milliseconds
boolean lastConnected = false;                 // state of the connection last time through the main loop
const unsigned long postingInterval = 2*1000; // delay between 2 datapoints, 30s

String returnValue = ""; 
boolean ResponseBegin = false;

void setup() {
  pinMode(3,OUTPUT);
  Wire.begin();
  Serial.begin(9600);
  // start the Ethernet connection with DHCP:
  if (Ethernet.begin(mac) == 0) {
    Serial.println("Failed to configure Ethernet using DHCP");
    for(;;)
      ;
  }

  else {
  Serial.println("Ethernet configuration OK");
  }
}

void loop() {

// if there's incoming data from the net connection.
  if (client.available()) {
    char c = client.read();
  // Serial.print(c);
      if (c == '{')
        ResponseBegin = true;
      else if (c == '}')
        ResponseBegin = false;
      if (ResponseBegin)
        returnValue += c;   
  }

  if (returnValue.length() !=0 && (ResponseBegin == false)){
    Serial.println(returnValue);
    if (returnValue.charAt(returnValue.length() - 1) == '1') {
      if(AcStateOff==true&&flag==0||FanStateOff==true&&flag==1||TVStateOff==true&&flag==2){
        int changetimes=flag-currentmode;
        if(changetimes<0)
          changetimes+=3;
        for(int cmtimes=0;cmtimes<changetimes;cmtimes++){
          Serial.println("changemode");
          irsend.sendNEC(0xFF9867,32);
          delay(400);
        }
        irsend.sendNEC(0xFFA25D,32);
         if(flag==0){
          Serial.println("turn on the AC"); 
          currentmode=0;
          AcStateOff=false;
        }
        else if(flag==1){
          Serial.println("turn on the Fan");
          currentmode=1;
          FanStateOff=false;
        }
        else if(flag==2){
          Serial.println("turn on the TV"); 
          currentmode=2;
          TVStateOff=false;
        }
      }
    } 
    else if(returnValue.charAt(returnValue.length() - 1) == '0') {
      if(AcStateOff==false&&flag==0||FanStateOff==false&&flag==1||TVStateOff==false&&flag==2){
        int changetimes=flag-currentmode;
        if(changetimes<0)
          changetimes+=3;
        for(int cmtimes=0;cmtimes<changetimes;cmtimes++){
          Serial.println("changemode");
          irsend.sendNEC(0xFF9867,32);
          delay(400);
        }
        irsend.sendNEC(0xFFA25D,32);
        if(flag==0){
          Serial.println("turn off the AC"); 
          currentmode=0;
          AcStateOff=true;
        }
        else if(flag==1){
          Serial.println("turn off the Fan");
          currentmode=1;
          FanStateOff=true;
        }
        else if(flag==2){
          Serial.println("turn off the TV"); 
          currentmode=2;
          TVStateOff=true;
        }
      }
    }

    returnValue = "";
    flag ++;
  }

  

// if there's no net connection, but there was one last time   
// through the loop, then stop the client:
  if (!client.connected() && lastConnected) {
    Serial.println();
    Serial.println("disconnecting.");
    client.stop();
  }


// if you're not connected, and ten seconds have passed since
// your last connection, then connect again and send data:

  if(!client.connected() && (millis() - lastConnectionTime > postingInterval)) {
    // read sensor data, replace with your code
    //int sensorReading = readLightSensor();
    Serial.print("yeelink:");
    if (flag<3){
      //get data from server
      getData();   
    }
    else if(flag==3){//put data to server
      postData(readData());
      flag =4;
    }   
    else if(flag==4) {
      postData2(readData2()); 
      flag =0;
    }   

   // note the time that the connection was made or attempted:
    lastConnectionTime = millis();

  }

  // store the state of the connection for next time through
  // the loop:
  lastConnected = client.connected();
}


// this method makes a HTTP connection to the server and get data back
void getData(void) {
  // if there's a successful connection:
  if (client.connect(server, 80)) {
    Serial.println("connecting...");
    // send the HTTP GET request:
    client.print("GET /v1.0/device/");
    client.print(DEVICEID);
    client.print("/sensor/");
//   client.print(SENSORID);
    client.print(SENSORno[flag]);
    client.print("/datapoints");
    client.println(" HTTP/1.1");
    client.println("Host: api.yeelink.net");
    client.print("Accept: *");
    client.print("/");
    client.println("*");
    client.print("U-ApiKey: ");
    client.println(APIKEY);
    client.println("Content-Length: 0");
    client.println("Connection: close");
    client.println(); 
    Serial.println("print get done.");  
  }
  else{
    // if you couldn't make a connection:
    Serial.println("connection failed");
    Serial.println();
    Serial.println("disconnecting.");
    client.stop();
  }
  // note the time that the connection was made or attempted:
  //  lastConnectionTime = millis();
  lastConnectionTime = millis();
}  

// this method makes a HTTP connection to the server:
void postData(int thisData) {
  // if there's a successful connection:
  if (client.connect(server, 80)) {
    Serial.println("connecting...");
    // send the HTTP PUT POST request:
    client.print("POST /v1.0/device/");
    client.print(DEVICEID);
    client.print("/sensor/");
    client.print(8035);
    client.print("/datapoints");
    client.println(" HTTP/1.1");
    client.println("Host: api.yeelink.net");
    client.print("Accept: *");
    client.print("/");
    client.println("*");
    client.print("U-ApiKey: ");
    client.println(APIKEY);
    client.print("Content-Length: ");

    // calculate the length of the sensor reading in bytes:
    // 8 bytes for {"value":} + number of digits of the data:
    int thisLength = 10 + getLength(thisData);
    client.println(thisLength);
    client.println("Content-Type: application/x-www-form-urlencoded");
    client.println("Connection: close");
    client.println();
    // here's the actual content of the PUT request:
    client.print("{\"value\":");
    client.print(thisData);
    client.println("}");
    Serial.print(thisData);
  }
  
  else {
    // if you couldn't make a connection:
    Serial.println("connection failed");
    Serial.println();
    Serial.println("disconnecting.");
    client.stop();
  }
   // note the time that the connection was made or attempted:
  lastConnectionTime = millis();
}

void postData2(int thisData) {
  // if there's a successful connection:
  if (client.connect(server, 80)) {
    Serial.println("connecting...");
    // send the HTTP PUT POST request:
    client.print("POST /v1.0/device/");
    client.print(DEVICEID);
    client.print("/sensor/");
    client.print(8558);
    client.print("/datapoints");
    client.println(" HTTP/1.1");
    client.println("Host: api.yeelink.net");
    client.print("Accept: *");
    client.print("/");
    client.println("*");
    client.print("U-ApiKey: ");
    client.println(APIKEY);
    client.print("Content-Length: ");

    // calculate the length of the sensor reading in bytes:
    // 8 bytes for {"value":} + number of digits of the data:
    int thisLength = 10 + getLength(thisData);
    client.println(thisLength);

    client.println("Content-Type: application/x-www-form-urlencoded");
    client.println("Connection: close");
    client.println();

    // here's the actual content of the PUT request:
    client.print("{\"value\":");
    client.print(thisData);
    client.println("}");
    Serial.print(thisData);
  }
  
  else {
    // if you couldn't make a connection:
    Serial.println("connection failed");
    Serial.println();
    Serial.println("disconnecting.");
    client.stop();
  }
   // note the time that the connection was made or attempted:
  lastConnectionTime = millis();
}

// This method calculates the number of digits in the
// sensor reading.  Since each digit of the ASCII decimal
// representation is a byte, the number of digits equals
// the number of bytes:
int getLength(int someValue) {
  // there's at least one byte:
  int digits = 1;
  // continually divide the value by ten,
  // adding one to the digit count for each
  // time you divide, until you're at 0:
  int dividend = someValue /10;
  while (dividend > 0) {
    dividend = dividend /10;
    digits++;
  }
  // return the number of digits:
  return digits;
}

int readData(void)
{
  int dat;
  int chk = DHT11.read(DHT11PIN);
  return dat=(float)DHT11.temperature;
}

int readData2(void)
{
  int dat;
  int chk = DHT11.read(DHT11PIN);
  return dat=(float)DHT11.humidity;
}

